%%HP: T(3)A(D)F(.);
@ SIGNIN - On Site Sign-In, Registration
@ RBJ 6/01/90 
DIR
  IDATA \<< 
    'Fname'   In
    'Lname'   In
    'PayMeth' In                            @ E.G. Cash, Chk #
    'Fee'     In
    'Street'  In
    'City'    In
    'State'   In
    'Zip'     In
    'Country' In
    'Hphone'  In
    'Wphone'  In
  \>>
  PRINT  \<<  
    CLLCD -1 'Row' STO 
    "    CHIP Handheld"  Ou
    "     Conference"    Ou
    "    June 2, 1990"   Ou
    ""                   Ou
    STD
    "  Registration # " Rnum +  Ou
    "Received $" Fee +            Ou
    "  (" PayMeth + ")" +         Ou
    CLLCD -1 'Row' STO

    Fname " " + Lname +             Ou
    Street                          Ou
    City ", " + State + " " + Zip + Ou
    IF Country SIZE THEN Country           Ou END
    IF Hphone  SIZE THEN "Home: " Hphone + Ou END
    IF Wphone  SIZE THEN "Work: " Wphone + Ou END
    7 FREEZE
  \>>
  Next  \<< 
    CLEAR
    Rnum Fname Lname 
    Street City State Zip Country
    Hphone Wphone
    Fee PayMeth 
    DEPTH \->LIST
    "R" Rnum + OBJ\-> ATTD STO UPDIR
    'Rnum' INCR Hnum MAX DUP 'Rnum' STO 'Hnum' STO
    "Next #:" Rnum + "\010" + 1 DISP 1 FREEZE
  \>>
  Restore \<< 
    "R" SWAP + OBJ\-> ATTD RCL UPDIR
    LIST\-> DROP
    'PayMeth' STO
    'Fee'     STO
    'Wphone'  STO
    'Hphone'  STO
    'Country' STO
    'Zip'     STO
    'State'   STO
    'City'    STO
    'Street'  STO
    'Lname'   STO
    'Fname'   STO
    'Rnum'    STO
    "Restored #:" Rnum + "\010" + 1 DISP 1 FREEZE
  \>>
  
  Rnum  60
  Hnum   0

  ATTD DIR END

  Kill   \<< UPDIR 'SIGNIN' PGDIR 18 MENU \>>

  In \<<                                    @ Given Variable Name
    DUP "" + { "" \Ga } INPUT SWAP STO
  \>>
  Ou \<< 
    IF 9 FS? THEN PR1 END
    'Row' INCR 7 MOD 1 + DISP
  
  \>>
  Fname   "Bill"
  Lname   "Jones"
  PayMeth "Chk 3456"                        @ E.G. Cash, Chk #
  Fee     "25"
  Street  "234 East 76th St"
  City    "Chicago"
  State   "IL"
  Country "USA"
  Zip     "60625"
  Hphone  "312/455-8999"
  Wphone  "708/234-4678"
  Row     0

END

