%%HP: T(3)A(D)F(.);
DIR
  GKB
  \<< 2. FIX
    IF DEPTH 4. \>=
    THEN 'B2' STO
'L2' STO 'B1' STO
'L1' STO
    END
    IF 'L1' VTYPE 0.
== 'B1' VTYPE 0. ==
AND 'L2' VTYPE 0. ==
AND 'B2' VTYPE 0. ==
AND
    THEN
      IF L2 L1 <
      THEN L1 L2 'L1'
STO 'L2' STO B1 B2
'B1' STO 'B2' STO
      END
      IF L1 ABS 180.
\<= B1 ABS 90. \<= AND L2
ABS 180. \<= AND B2 ABS
90. \<= AND
      THEN DEG SPHERE
1. L1 90. B1 - \->V3
'P1' STO 1. L2 90. B2
- \->V3 'P2' STO RECT
P1 P2 DOT 'COSB' STO
COSB ACOS '\Gb' STO \Gb
D\->R 6371. * 'b' STO
90. B1 - COS COSB 90.
B2 - COS * - \Gb SIN
90. B2 - SIN * DUP
        IF 0. \=/
        THEN / ACOS
DUP
          IF ABS .005
<
          THEN DROP
0.
          END
        ELSE DROP
DROP "**.**"
        END 'k2' STO
90. B2 - COS 90. B1 -
COS COSB * - 90. B1 -
SIN \Gb SIN * DUP
        IF 0. \=/
        THEN / ACOS
DUP
          IF ABS .005
<
          THEN DROP
0.
          END
        ELSE DROP
DROP "**.**"
        END 'k1' STO
"Gro\Gbkreisbogen P1\->P2
 L1="
L1 \->STR + "\^o B1=" +
B1 \->STR + "\^o" +
"
 L2=" + L2 \->STR +
"\^o B2=" + B2 \->STR +
"\^o" + "
 b = " + b
\->STR +
" km
 \<) P1\->P2 : \Gb=" +
\Gb \->STR +
"\^o
 \<) bei P1: k1=" +
k1 \->STR +
"\^o
 \<) bei P2: k2=" +
k2 \->STR + "\^o" + CLLCD
1. DISP 0. WAIT DROP
        \<< { LOE P1 P2
k1 \Gb k2 b COSB }
PURGE
        \>> 'LOE' STO
      ELSE 4000. .1
BEEP
"Werte nicht im
 G\252ltigkeits-
     bereich.
Berechnung
 nicht m\246glich!"
MSGBOX
      END
    ELSE
"Gro\Gbkreis-Bogen:
  Ort P1: L1 B1 in \^o
  Ort P2: L2 B2 in \^o
 Bedingungen: L1 < L2
  Ost = (+) West= (-)
  Nord= (+) S\252d = (-)
bzw. Men\252 berichtigen!"
4000. .1 BEEP CLLCD
1. DISP 0. WAIT DROP
    END
    IF 'L1' VTYPE -1.
\=/
    THEN
      \<< { L1 B1 L2 B2
LOEP } PURGE RECT
      \>> 'LOEP' STO
    END
  \>>
  KOO
  \<< STD
    WHILE CLLCD
"      " KOO1 SIZE
\->STR + " ORTE" + KOO1
1. CHOOSE
    REPEAT EVAL
    END
  \>>
  KOO1 { { "DCF 77.5"
  \<< 9. 50.02
  \>> } {
"Greenwich (Observ.)"
  \<< 0. 51.45
  \>> } { "HP49Forum"
  \<< 11.575 48.275
  \>> } { "Hamburg"
  \<< 10. 53.55
  \>> } { "Kairo"
  \<< 31.25 30.05
  \>> } {
"M\252nchen Airport"
  \<< 11.6 48.35
  \>> } { "New York"
  \<< -75. 43.
  \>> } {
"Nordpol (magnetisch)"
  \<< -101.82 77.32
  \>> } {
"Nordpol(geographisch)"
  \<< 0. 90.
  \>> } {
"S\252dpol (magnetisch)"
  \<< 139.47 -65.88
  \>> } { "Tokyo"
  \<< 139.75 35.65
  \>> } }
END